// Sunstone Utility Macros
//  by Opxe
//     opxe@puddleby.info
//     http://opxe.pucks.org
//  Based on noivad's quick reply macro (noivad@NOSPAMMEmac.com)

//  I suggest downloading this page verbatim and keeping it a separate file
//  and just using: include "tc_macro" in your Default macro file. 

// goscan				start
// noscan				stop
// t?					give the current target
// tmessages			toggles Status area feedback on and off. (Default is on.)
// tr <text>			think to exile who thought to you last
// ts <name> <text>		manually sets the target and messages them if you included a message.
// t <text>				normal global think
// tt <name> <text>		think to individual
// tc <text>			think to clan
// tg <text>			think to group
// tga <name>			add name to your group
// tgr <name>			remove name from your group
// tgl					list members your group

// global variables required
set name_position   2			// set to 0 if you dont use time stamps

set ssTarget		"" 
set scanBreak		0
set messageStatus	1

equip_think_tool
{
if @my.forehead.item != "sungem"
	"/equip sungem\r"
end if
}

"t"
{
call equip_think_tool
"/think " @text "\r"
}

"tt"
{
call equip_think_tool
"/thinkto " @text "\r"
}

"tc"
{
call equip_think_tool
"/thinkclan " @text "\r"
}

"tg"
{
call equip_think_tool
"/thinkgroup " @text "\r"
}

"tga"
{
"/useitem " @think_tool_name " /add " @text
}

"tgr"
{
"/useitem " @think_tool_name " /remove " @text
}

"tgl"
{
"/useitem " @think_tool_name " /who"
}

"goscan" call goscan

goscan
{
setglobal scanBreak 0 
set @env.key_interrupts false
set @env.click_interrupts false
if messageStatus == 1
	message "Scanner On"
end if
call Scanner
}

Scanner
{
label scanTop
if scanBreak == 1      //stops macro if "noscan" is typed
	goto scanEnder
else
	set scanText @env.textLog
	if scanText < "thinks to you"
		if ssTarget != scanText.word[name_position]  
			setglobal  ssTarget scanText.word[name_position]
			setglobal feedback 1 
			pause 4
		end if
		if messageStatus == 1
			if feedback == 1					
				message "tr target: " ssTarget 
				setglobal feedback 0 			
			end if
		end if	
	else
		pause 1
		goto scanTop
	end if
	goto scanTop
end if

label buggy								//After time some infinite loops run 
										//away 
Message "Bug Detected:"					//on you. So, I place these messages
pause 2									//in to let you know if the macro
Message "**Use ""noscan""  to halt***"	//has jumped out of the regular loop
pause 120								//<--gives you time to escape the loop. 

label scanEnder
if messageStatus == 1
	message "Scanner Off"
end if
set @env.key_interrupts true		//Kludges to try  
set @env.click_interrupts true		//Kludges to stop
pause 300							//Kludges a run away macro
}

"noscan"
{
setglobal scanBreak 1	
}

"tr"
{
call equip_think_tool
"/thinkto " ssTarget " " @text "\r"
pause 4
}

"t?"
{
Message "Reply Target: " ssTarget
}

"ts"
{
setglobal ssTarget @text.word[0]
if messageStatus == 1
	message "Targeting: " ssTarget "."
end if
pause 1

call equip_think_tool

if @text.num_words > 1
	"/thinkto " @text "\r"
end if
}

"tmessages"
{
if messageStatus == 1
	setglobal messageStatus 0
	goto END
else
	setglobal messageStatus 1
	message "Messages On"
end if
label END
}